Can someone share their calculation to force phone number entry to be displayed with a specific convention?
I'd like parentheses around the area code (xxx), followed by a space then the 3 digit prefix, then a hyphen and the 4 digit suffix.
ex. (xxx) xxx-xxxx
Thanks
The following calculation will take a 10-digit or a 7-digit phone number located in a field named ThePhoneNumberField.
It does not handle country codes or extensions.
Let([
~phoneDigits = Filter(ThePhoneNumberField; "0123456789" );
~areaCode = Left(~phoneDigits; 3);
~localPhone = Right(~phoneDigits; 7); // Also handles case where no area code is entered.
~prefix = Left(~localPhone; 3);
~line = Right(~localPhone; 4)
];
Case(
Length(~phoneDigits) = 10; "(" & ~areaCode & ") " & ~prefix & "-" & ~line;
Length(~phoneDigits) = 7; ~prefix & "-" & ~line;
"" // Put ThePhoneNumberField here if you would prefer that result for entries not 7 or 10 digits.
)
)
-Tom
I have a custom function (but a field could be called, instead of passing the parameter):
Let(
[ phf = Filter ( phone_num ; "0123456789" ) // only numerals
; ext = Filter ( phone_num ; ",xX" ) // probably has an extension
; ext = If ( not IsEmpty(ext) ; GetValue ( Substitute ( phone_num ; ext ; ¶ ) ; 2 ) ; "" )
; phl = Length ( phf )
; phph = Case
( phl = 10 ; Left ( phf ; 3 ) & "-" & Middle ( phf ; 4 ; 3 ) & "-" & Right ( phf ; 4 ) // xxx-xxx-xxxx
; phl = 7 ; Left ( phf ; 3 ) & "-" & Middle ( phf ; 4 ; 4 ) // xxx-xxx
; phl > 10 ; Left ( phf ; 3 ) & "-" & Middle ( phf ; 4 ; 3 ) & "-" & Middle ( phf ; 7 ; 4 ) & If ( not IsEmpty(ext) ; "," & ext ; "" ) // xxx-xxx-xxxx,xxx
; phf // default
)
]; phph
)
I've chosen to use the "-" instead of the (...) for the area code, but that could be added in there.
Beverly
Creating a data input mask for formatting telephone numbers | FileMaker